--------------------------------------------------------------
--# GtkAboutDialog -- a handy way to display your program info
--------------------------------------------------------------

include GtkEngine.e

constant docs = `<b><u>About Dialog</u></b>

Convenient, pre-built way to show 
license and credits for your program.

Click the About button.
`
constant dlg = create(GtkAboutDialog,{
	{"title","About..."},
	{"icon","thumbnails/mongoose.png"},
	{"logo","thumbnails/eugtk.png"},
	{"comments","This is a test of the GtkAboutDialog\nwritten in Euphoria"},
	{"program name","A wrapper for GTK3"},
	{"version","Version "& version},
	{"copyright",copyright},
	{"authors",{
		"Irv Mullins <irvmull@gmail.com>",
		"With the help of the",
		"OpenEuphoria community http://openeuphoria.org"}
		},
	{"artists",{"Van Goo","P. Kasso","R.E.M Brandt"}},
	{"website","http://OpenEuphoria.org"},
	{"website label","OpenEuphoria"},
	{"license",LGPL & "http://www.gnu.org/licenses/lgpl.html\n"},
	{"add credit section","Testers",{"Al K. Seltzer","Jim Beam"}}})

constant win = create(GtkWindow,"size=200x80,border_width=10,position=1,$destroy=Quit")

constant panel = add(win,create(GtkBox,VERTICAL,10))

constant lbl1 = add(panel,create(GtkLabel,{{"markup",docs}}))

constant box = add(panel,create(GtkButtonBox))
	add(box,
	{create(GtkButton,"gtk-quit","Quit"),
	 create(GtkButton,"gtk-about",_("ShowAboutDialog"))})

show_all(win)
main()

--------------------------
function ShowAboutDialog()
--------------------------
	get(dlg,"run")
	set(dlg,"hide")
return 1
end function